1
$\begingroup$

I'm trying to implement a polygenic score pipeline in WDL and I'm quite new to this pipeline management.

The first step of the pipeline takes a file of GWAS summary statistics and splits it by chromosome.

The corresponding wdl task:

task split {
    input {
        File gwas
        String output_prefix
    }

    command {
        ./splitGwas -i ${gwas} -o ${output_prefix}
    }

    output {
        Array [File] gwas_by_chr = glob("${output_prefix}_*.assoc")
    }
}

The next part of the process is to compute posterior effects of SNPs by chromosome. The inputs to this task are going to be the files split by chromosome in the previous step and an LD matrix for the chromosome.

The corresponding wdl call would be something like this:

Array [File] ld_matrices = read_lines(file_of_ld_matrices_by_chr)

scatter(pair in zip(split.gwas_by_chr, ld_matrices)) {
    call sbayes.run {
        input:
            GCTB = gctb_executable_path,
            gwas = pair.left,
            ld_matrix = pair.right,
            output_prefix = out
    }
}

Since I'm grabbing the split files using glob in the previous step, I do not particularly know which element in the array corresponds to which chromosome. So I would be making a mistake if I zip the summary stats for one chromosome with the LD matrix corresponding to a different chromosome.

The programmatic way would be to iterate the scatter over chromosome name but then I would lose the ability to specify the dependency between the two tasks.

Is there a better way to do this?

Cross posted on biostars (https://www.biostars.org/p/434582/) so pardon me if that is discouraged.

$\endgroup$
2
  • $\begingroup$ Two questions: 1. Would it be possible for file_of_ld_matrices_by_chr to be in JSON format, instead of just a list a list of file paths? 2. What does the name of the file produced by splitGwas look like (ie. what's in between the prefix and the .assoc? $\endgroup$
    – DavyCats
    Apr 27, 2020 at 11:47
  • $\begingroup$ 1. Yes, I can put the LD matrices in JSON 2. The file names produced by split GWAS have the names ${prefix}_chromosome.assoc so if the user supplied prefix string is T2D as in type 2 diabetes, the outputs are T2D_1.assoc, T2D_2.assoc ... T2D_22.assoc $\endgroup$
    – Vivek
    Apr 27, 2020 at 14:31

1 Answer 1

1
$\begingroup$

You could use the sub function to obtain the chromosome from the globbed file names and then use that to retrieve the correct LD matrices from a Map (see read_map or read_json).

eg.:

Map[String, String] ld_matrices = read_json(file_of_ld_matrices_by_chr)

scatter(gwas_for_chr in split.gwas_by_chr) {
    String chr = sub(sub(gwas_for_chr, prefix, ""), "\.assoc$", "")

    call sbayes.run {
        input:
            GCTB = gctb_executable_path,
            gwas = gwas_for_chr,
            ld_matrix = ld_matrices[chr],
            output_prefix = out
    }
}

The file_of_ld_matrices_by_chr would have to look like this:

{
  "chr1": "/path/to/file1",
  "chr2": "/path/to/file2"
}
$\endgroup$
1
  • $\begingroup$ This works perfectly. $\endgroup$
    – Vivek
    Apr 27, 2020 at 15:20

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.